Menentukan Takaran Pupuk Tanaman Melalui Handphone

Penentuan jumlah takaran pupuk sangat penting bagi pemeliharaan tanaman. Setiap tanaman memiliki jumlah takaran pupuk masing-masing. Dengan menggunakan sensor flow control kita dapat menghitung jumlah cairan yang mengalir melalui sensor berdasarkan laju alirannya.

[membership level=”0,1,2,4″]

1. Alat / Bahan

• Arduino IDE                                     Download disini
• Library: Blynk                                  Download disini
• Library: ESP8266                            Download disini
• NodeMCU ESP8266                      1 Buah
• Flow Sensor                                   1 Buah
• Relay 1ch                                       1 Buah
• Project Board                                  1 Buah
• Kabel Jumper                                  Secukupnya
• Smartphone                                     1 Buah

Untuk mendapatkan komponen elektronik di atas silahkan temukan disini.

2. Skema Rangkaian

Gambar Rangkaian Menentukan Takaran Pupuk Tanaman Melalui Handphone

Keterangan:

• VU – VCC Flow Sensor, VCC Relay
• GND – GND Flow Sensor, GND Relay
• D4 – Data Relay
• D7 – Data Flow Sensor

[/membership]

3. Layout Blynk

Keterangan:

• Jumlah Pupuk (Labeled Value)
  • Input V0, Low = 0, High = 9999
  • Label = /pin./ ml
• Setting Pupuk (Numeric Input)
  • Output V2, Low = 0, High = 9999
• Reset (Button)
  • Output V1, Low = 0, High = 1
  • Mode = Push
  • Label OFF = reset, On = reset

4. Langkah Kerja

1. Siapkan alat dan bahan yang akan digunakan
2. Lakukan proses wiring dengan menggunakan Gambar skematik rangkaian diatas
3. Buka software Arduino IDE yang telah terinstal pada laptop/komputer
4. Unduh semua library di atas dan masukkan libray tersebut dengan cara buka Arduino IDE pilih Sketch->Include Library->Add.Zip Library 
5. Ketikkan sketch program pada halaman Arduino IDE
6. Sesuaikan Auth Tokens dengan proyek aplikasi Blynk. Cara setting dan mendapatkan Auth Tokens dapat dilihat pada tutorial berikut:
   Setting Blynk untuk NodeMCU ESP8266
7. Ganti ssid dan pass dengan nama wifi dan password wifi yang kalian gunakan
8. Lakukan proses uploading program
9. Buka aplikasi Blynk
10. Buat layout Blynk seperti gambar di atas.
11. Tekan tombol Play pada aplikasi Blynk lalu tunggu hingga proyek kalian terhubung dengan aplikasi Blynk

5. Sketch Program

Belajar elektronika step by step dengan bantuan tangga belajar? Regitrasi dulu dan dapatkan konsultasi dari kami!

REGISTER SEKARANG>>

 
/* Program Menentukan Takaran Pupuk Tanaman Melalui Handphone dibuat oleh Indobot */

#include <ESP8266WiFi.h>              //Library ESP8266
#include <BlynkSimpleEsp8266.h>       //Library Blynk

char auth[] = "HoP9z23_PbWp-iEyMBYFGnnALYBvvcXS"; //Token
char ssid[] = "Wifi.id";                          //Nama wifi
char pass[] = "alam oye";                         //Password wifi

BlynkTimer timer;

#define relay 2
#define SENSOR 13

int batas = 0;

long currentMillis = 0;
long previousMillis = 0;
int interval = 1000;
float calibrationFactor = 4.5;
volatile byte pulseCount;
byte pulse1Sec = 0;
float flowRate;
unsigned int flowMilliLitres;
unsigned long totalMilliLitres;

void pulseCounter()
{
  pulseCount++;
}

void setup() {
  Blynk.begin(auth, ssid, pass);          //Inisialisasi token, wifi dan password
  timer.setInterval(1000L, sendSensor);   //Kirim data sensor

  pinMode(relay, OUTPUT);
  pinMode(SENSOR, INPUT_PULLUP);
  digitalWrite(relay, HIGH);

  pulseCount = 0;
  flowRate = 0.0;
  flowMilliLitres = 0;
  totalMilliLitres = 0;
  previousMillis = 0;

  attachInterrupt(digitalPinToInterrupt(SENSOR), pulseCounter, FALLING);
}

void loop() {
  Blynk.run();                        //Jalankan pembacaan Blynk
  timer.run();

  currentMillis = millis();
  if (currentMillis - previousMillis > interval) {
    
    pulse1Sec = pulseCount;
    pulseCount = 0;

    flowRate = ((1000.0 / (millis() - previousMillis)) * pulse1Sec) / calibrationFactor;
    previousMillis = millis();

    flowMilliLitres = (flowRate / 60) * 1000;

    totalMilliLitres += flowMilliLitres;
  }

  if(totalMilliLitres >= batas){
    digitalWrite(relay, HIGH);
  }
}

BLYNK_WRITE(V1){                      //Baca pin V1
  int tombolreset = param.asInt();
  if (tombolreset == 1){
    digitalWrite(relay, HIGH);
    totalMilliLitres = 0;
  }
}

BLYNK_WRITE(V2){                      //Baca pin V1
  batas = param.asInt();
  digitalWrite(relay, LOW);
}

void sendSensor(){                  //Kirim data sensor
  Blynk.virtualWrite(V0, totalMilliLitres);
}

Kesimpulan:

Input jumlah pupuk di inputkan pada aplikasi Blynk. Ketika telah menginputkan jumlah pupuk, otomatis relay akan ON. Relay ini dapat dihubungkan pada pompa maupun solenoid valve. Ketika jumlah pupuk sudah sesuai dengan input maka relay akan OFF.

[/membership]

Bikin project tanpa ribet beli komponen sana-sini? Starter Kit Arduino/IoT bisa jadi solusi mu!

PESAN STARTER KIT SEKARANG>>